Initial commit

## Example files for the title:  

# Mastering Algorithms with Perl, by Jarkko Hietaniemi

[![Mastering Algorithms with Perl, by Jarkko Hietaniemi](http://akamaicovers.oreilly.com/images/9781565923980/cat.gif)](https://www.safaribooksonline.com/library/view/title/1565923987//)

The following applies to example files from material published by O’Reilly Media, Inc. Content from other publishers may include different rules of usage. Please refer to any additional usage rights explained in the actual example files or refer to the publisher’s website.

O'Reilly books are here to help you get your job done. In general, you may use the code in O'Reilly books in your programs and documentation. You do not need to contact us for permission unless you're reproducing a significant portion of the code. For example, writing a program that uses several chunks of code from our books does not require permission. Answering a question by citing our books and quoting example code does not require permission. On the other hand, selling or distributing a CD-ROM of examples from O'Reilly books does require permission. Incorporating a significant amount of example code from our books into your product's documentation does require permission.

We appreciate, but do not require, attribution. An attribution usually includes the title, author, publisher, and ISBN.

If you think your use of code examples falls outside fair use or the permission given here, feel free to contact us at <permissions@oreilly.com>.

Please note that the examples are not production code and have not been carefully testing. They are provided "as-is" and come with no warranty of any kind.

# $index = binary_search( \@array, $word )

#   @array is a list of lowercase strings in alphabetical order.

#   $word is the target word that might be in the list.

#   binary_search() returns the array index such that $array[$index]

#   is $word.

sub binary_search {

    my ($array, $word) = @_;

    my ($low, $high) = ( 0, @$array - 1 );

    while ( $low <= $high ) {              # While the window is open

        my $try = int( ($low+$high)/2 );      # Try the middle element

        $low  = $try+1, next if $array->[$try] lt $word; # Raise bottom

        $high = $try-1, next if $array->[$try] gt $word; # Lower top

        return $try;     # We've found the word!

    }

    return;              # The word isn't there.

}

#!/usr/bin/perl -w

# Derived from code by Nathan Torkington.

use strict;

use integer;

my ($word, $file) = @ARGV;

open (FILE, $file) or die "Can't open $file: $!";

my $position = binary_search_file(\*FILE, $word);

if (defined $position) { print "$word occurs at position $position\n" }

else                   { print "$word does not occur in $file.\n" }

sub binary_search_file {

    my ( $file, $word ) = @_;

    my ( $high, $low, $mid, $mid2, $line );

    $low  = 0;                  # Guaranteed to be the start of a line.

    $high = (stat($file))[7];   # Might not be the start of a line.

    $word =~ s/\W//g;           # Remove punctuation from $word.

    $word = lc($word);          # Convert $word to lower case.

    while ($high != $low) {

        $mid = ($high+$low)/2;

        seek($file, $mid, 0) || die "Couldn't seek : $!\n";

        # $mid is probably in the middle of a line, so read the rest

        # and set $mid2 to that new position.

        $line = <$file>;

        $mid2 = tell($file);

        if ($mid2 < $high) {    # We're not near file's end, so read on.

            $mid  = $mid2;

            $line = <$file>;

        } else {   # $mid plunked us in the last line, so linear search.

            seek($file, $low, 0) || die "Couldn't seek: $!\n";

            while ( defined( $line = <$file> ) ) {

                last if compare( $line, $word ) >= 0;

                $low = tell($file);

            }

            last;

        }

        if (compare($line, $word) < 0) { $low  = $mid }

        else                           { $high = $mid }

    }

    return if compare( $line, $word );

    return $low;

}

sub compare {   # $word1 needs to be lowercased; $word2 doesn't.

    my ($word1, $word2) = @_;

    $word1 =~ s/\W//g; $word1 = lc($word1);

    return $word1 cmp $word2;

}

#!/usr/bin/perl

#

# bsearch - search for a word in a list of alphabetically ordered words

# Usage: bsearch word filename

$word = shift;                          # Assign first argument to $word

chomp( @array = <> );                   # Read in newline-delimited words,

                                        #     truncating the newlines

($word, @array) = map lc, ($word, @array); # Convert all to lowercase

$index = binary_search(\@array, $word);    # Invoke our algorithm

if (defined $index) { print "$word occurs at position $index.\n" }

else                { print "$word doesn't occur.\n" }

sub binary_search {

    my ($array, $word) = @_;

    my $low = 0;

    my $high = @$array - 1;

    while ( $low <= $high ) {

        my $try = int( ($low+$high) / 2 );

        $low  = $try+1, next if $array->[$try] lt $word;

        $high = $try-1, next if $array->[$try] gt $word;

        return $try;

    }

    return;

}

# factorial($n) computes the factorial of $n,

#   using an iterative algorithm.

sub factorial {

    my ($n) = shift;

    my ($result, $i) = (1, 2);

    for ( ; $i <= $n; $i++) {

        $result *= $i;

    }

    return $result;

}

# factorial_recursive($n) computes the factorial of $n,

#   using a recursive algorithm.

sub factorial_recursive {

    my ($n) = shift;

    return $n if $n <= 2;

    return $n * factorial_recursive($n - 1);

}

sub factorial_approx {

    return sqrt (1.5707963267949 * $_[0]) *

        (($_[0] / 2.71828182845905) ** $_[0]);

}